Prev: see equations on screen
Next: WORD 2007: automatically complete an often used word or phrase
From: StevelandMorris on 2 Jul 2008 13:43
I need to use the Microsoft Word 2007 pdf driver to covert hundreds of word
documents. I do not have adobe on the machine. I need to be able to convert
all .doc file in one directory and have them saved with the same filename but
the extention would be .pdf. I don't see why I would want a third party
product when word has the capability now. Any guidance would help.
From: Graham Mayor on 3 Jul 2008 00:28
The following macro will, using the Word 2007 PDF add-in, convert all the
documents in a folder selected with the macro to PDF format and save them in
the same folder as the document. The macro is configured to work with *.doc
files only which is what you asked for.

Sub SaveAllAsPDF()
Dim strFileName As String
Dim strDocName As String
Dim strPath As String
Dim oDoc As Document
Dim fDialog As FileDialog
Set fDialog = Application.FileDialog(msoFileDialogFolderPicker)

With fDialog
.Title = "Select folder and click OK"
.AllowMultiSelect = False
.InitialView = msoFileDialogViewList
If .Show <> -1 Then
MsgBox "Cancelled By User", , "List Folder Contents"
Exit Sub
End If
strPath = fDialog.SelectedItems.Item(1)
If Right(strPath, 1) <> "\" Then strPath = strPath + "\"
End With

If Documents.Count > 0 Then
Documents.Close SaveChanges:=wdPromptToSaveChanges
End If
If Left(strPath, 1) = Chr(34) Then
strPath = Mid(strPath, 2, Len(strPath) - 2)
End If
strFileName = Dir$(strPath & "*.doc")

While Len(strFileName) <> 0
Set oDoc = Documents.Open(strPath & strFileName)

strDocName = ActiveDocument.FullName
intPos = InStrRev(strDocName, ".")
strDocName = Left(strDocName, intPos - 1)
strDocName = strDocName & ".pdf"

oDoc.ExportAsFixedFormat OutputFileName:=strDocName, _
ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False,
OptimizeFor:= _
wdExportOptimizeForPrint, Range:=wdExportAllDocument, From:=1,
to:=1, _
Item:=wdExportDocumentContent, IncludeDocProps:=True, KeepIRM:=True,
_
CreateBookmarks:=wdExportCreateNoBookmarks, DocStructureTags:=True,
_
BitmapMissingFonts:=True, UseISO19005_1:=True

oDoc.Close SaveChanges:=wdDoNotSaveChanges
strFileName = Dir$()
Wend
End Sub

http://www.gmayor.com/installing_macro.htm

StevelandMorris wrote:
> I need to use the Microsoft Word 2007 pdf driver to covert hundreds
> of word documents. I do not have adobe on the machine. I need to be
> able to convert all .doc file in one directory and have them saved
> with the same filename but the extention would be .pdf. I don't see
> why I would want a third party product when word has the capability
> now. Any guidance would help.


 | 
Pages: 1
Prev: see equations on screen
Next: WORD 2007: automatically complete an often used word or phrase