Prev: Dup check 2 columns - need it to delete correct one
Next: I want to show only the first three columns
From: PAL on 1 Apr 2010 13:05
Can someone help with this formula, or perhaps come up with a simpler version?

=IF(E2="Startup","Yes",IF(E2="Enrollment Open","Yes",IF(E2="Enrollment
Closed","Yes",IF(E2="Treatment","Yes",IF(E2="Startup","Yes",IF(E2="On
Hold","Yes",IF(E2="Terminated,"Yes","")))))
From: Ms-Exl-Learner on 1 Apr 2010 13:14
=IF(OR(E2="Startup",E2="Enrollment Open",E2="Enrollment
Closed",E2="Treatment",E2="Startup",E2="On Hold",E2="Terminated"),"Yes","")

Remember to Click Yes, if this post helps!

--------------------
(Ms-Exl-Learner)
--------------------


"PAL" wrote:

> Can someone help with this formula, or perhaps come up with a simpler version?
>
> =IF(E2="Startup","Yes",IF(E2="Enrollment Open","Yes",IF(E2="Enrollment
> Closed","Yes",IF(E2="Treatment","Yes",IF(E2="Startup","Yes",IF(E2="On
> Hold","Yes",IF(E2="Terminated,"Yes","")))))
From: Dave Peterson on 1 Apr 2010 13:15
Maybe...

=IF(OR(E2={"startup","enrollment open","enrollment closed",
"treatment","startup","on hold","terminated"}),"Yes","")



PAL wrote:
>
> Can someone help with this formula, or perhaps come up with a simpler version?
>
> =IF(E2="Startup","Yes",IF(E2="Enrollment Open","Yes",IF(E2="Enrollment
> Closed","Yes",IF(E2="Treatment","Yes",IF(E2="Startup","Yes",IF(E2="On
> Hold","Yes",IF(E2="Terminated,"Yes","")))))

--

Dave Peterson
From: Teethless mama on 1 Apr 2010 14:21
Create a lookup list

A1: Startup
A2: Enrollment Open
A3: Enrollment Close
A4: Treatment
A5: On Hold
A6: Terminated


REPT("Yes",COUNTIF(A1:A6,E2))



"PAL" wrote:

> Can someone help with this formula, or perhaps come up with a simpler version?
>
> =IF(E2="Startup","Yes",IF(E2="Enrollment Open","Yes",IF(E2="Enrollment
> Closed","Yes",IF(E2="Treatment","Yes",IF(E2="Startup","Yes",IF(E2="On
> Hold","Yes",IF(E2="Terminated,"Yes","")))))
 | 
Pages: 1
Prev: Dup check 2 columns - need it to delete correct one
Next: I want to show only the first three columns